@echo off
setlocal enabledelayedexpansion

REM Umgebungsvariablen laden – immer relativ zum Batch-Datei-Verzeichnis
call "%~dp0\scripts\setenv.bat"

REM Kommandozeilenparameter prüfen und Defaults verwenden, falls Parameter fehlen
if not "%~2"=="" (
    set LAYERS=%~2
) else if not defined LAYERS (
    set LAYERS=D-1,D-5
)

if not "%~3"=="" (
    set TOLERANCE=%~3
) else if not defined TOLERANCE (
    set TOLERANCE=0.05
)

if not "%~4"=="" (
    set MARK_RADIUS=%~4
) else if not defined MARK_RADIUS (
    set MARK_RADIUS=200
)

REM Analyse starten
if "%~1"=="" (
    echo Keine Datei angegeben. Suche in input\ ...
    for %%f in ("%INPUT_DIR%\*.dxf") do (
        echo Starte Analyse fuer %%f mit Layer=!LAYERS!, Tolerance=!TOLERANCE!, Mark Radius=!MARK_RADIUS!
        python "%SCRIPT_DIR%\analyze.py" "%%f" "!LAYERS!" "!TOLERANCE!" "!MARK_RADIUS!"
    )
) else (
    echo Starte Analyse fuer %~1 mit Layer=%LAYERS%, Tolerance=%TOLERANCE%, Mark Radius=%MARK_RADIUS%
    python "%SCRIPT_DIR%\analyze.py" "%~1" "%LAYERS%" "%TOLERANCE%" "%MARK_RADIUS%"
)

echo Fertig.
pause