;------------------------------------------------------------------------;
; Bügelplätze zeichnen  - TYP 5 -                                        ;
; -----------------------------------------------------------------------;
; 28.09.93 / 13.6.98                                                     ;
;------------------------------------------------------------------------;
(defun Dbox (/ Dat)
  (setq Dat (load_dialog (strcat lw "/acadsst/module/b_typ5.dcl")))
  (if (not (new_dialog "b_typ5" Dat)) (exit))
  (set_tile "L1"      m_L1)
  (set_tile "L2"      m_L2)
  (set_tile "K0"      m_K0)
  (set_tile "ART"     m_ART)
  (SetDia)
  (ACTION_TILE "ART"  "(zeig_dia)")
  (action_tile "accept" "(SetPara) (done_dialog)")
  (action_tile "cancel" "(exit) (done_dialog)")
  (start_dialog)
  (unload_dialog Dat)
)

(defun SetDia()
  (setq breite (dimx_tile "anzeige"))
  (setq hoehe  (dimy_tile "anzeige"))
  (start_image "anzeige")
  (FILL_IMAGE 0 0 breite hoehe -18)
  (if (= m_ART "ART_1")  ; Nr 1
    (slide_image 0 0 breite hoehe "arbplz(btyp05_1)")
  )
  (if (= m_ART "ART_2")  ; Nr 2
    (slide_image 0 0 breite hoehe "arbplz(btyp05_2)")
  )
  (if (= m_ART "ART_3")  ; Nr 3
    (slide_image 0 0 breite hoehe "arbplz(btyp05_3)")
  )
  (end_image)
)

(defun zeig_dia()
  (setq m_ART (get_tile "ART"))
  (SetDia)
)

(defun SetPara ()
  (setq m_L1       (get_tile "L1")     ; Breite
	  m_K0       (get_tile "K0")     ; Anzahl Plätze
	  m_ART      (get_tile "ART")    ; Art
	  m_L2       (get_tile "L2")     ; Streckenabstand
  )
)

(defun datain()  
  (setq L1     (atoi m_L1))               ; Streckenabstand
  (setq K0     (atoi m_K0))               ; Anzahl Plätze
  (setq ART    (atoi (substr m_ART 5 1))) ; Art
  (setq L2     (atoi m_L2))               ; Tiefe
  ;----------------------------------------------------------------------;
  ; >>>>>> Eingabeteil <<<<<<                                            ;
  ;----------------------------------------------------------------------;
  (setq P0 (getpoint "\nUntere linke Ecke definieren: "))
  (initget (+ 2 4))
  ;----------------------------------------------------------------------;
  ; >>>>>> Prüfung ob die Grenzwerte eingehalten sind <<<<<<             ;
  ;----------------------------------------------------------------------;
  (while (or (< L1 2250) (> L1 6000))      
    (initget (+ 1 2 4))
    (setq L1 (getreal "\nBreite eingeben [2250-6000]: "))
  )
  (while (or (< L2 700) (> L2 2000))      
    (initget (+ 1 2 4))
    (setq L2 (getint "\nStreckenabstand eingeben [700-2000]: "))
  )
)

(defun punkte()
  ;-----------------------------------------------------------------------;
  ; >>>>>> Konstruktionspunkte definieren <<<<<<                          ;
  ;-----------------------------------------------------------------------;
  (setq P1  (list (+ (car p0)  425       ) (cadr p0)))
  (setq P2  (list (+ (car p1)  L2        ) (+ (cadr p1) L2)))
  (setq P3  (list (+ (car p1)  (* L2 2)  ) (cadr p1)))
  (setq P4  (list (+ (car p0)  800       ) (cadr p0)))
  (setq P5  (list (+ (car p0)  825       ) (+ (cadr p0) 400)))
  (setq P6  (list (- (car p2)  283       ) (- (cadr p2) 283)))
  (setq P7  (list (+ (car p2)  400       ) (cadr p2)))
  (setq P8  (list (+ (car p2)  283       ) (- (cadr p2) 283)))
  (setq P9  (list (- (car p3)  400       ) (+ (cadr p3) 400)))
  (setq P10 (list (- (car p3)  375       ) (cadr p3)))
  (setq P11 (list (+ (car p3)  425       ) (cadr p3)))
  (setq P12 (list (+ (car p0)  L1        ) (cadr p0)))
  (setq P13 (list (+ (car p2)  (- L1 400)) (cadr p2)))
  (setq P14 (list (- (car p0)  200       ) (- (cadr p0) 400 )))
  (setq P15 (list (+ (car p13) 200       ) (+ (cadr p2) 2000)))
  (cond
    ((= ART 1)
    (setq P16 (list (+ (car p0) 100)                 (cadr p0)))
    (setq P17 (list (+ (car p2) (- (/ L2 2) 187.5))  (- (cadr p2) (- (/ L2 2) 187.5))))
    (setq P18 (list (+ (car p2) (/ L1 2))            (cadr p2)))
    (setq P19 (list (car p2)                         (- (cadr p18) L2))) 
    (setq P20 (list (+ (car p1) 250)                 (+ (cadr p1) 250)))
    (setq P21 (list (+ (car p2) (- (/ L1 2) 300))    (+ (cadr p2) 2000)))
    (setq P22 (list (- (car p21) 700)                (- (cadr p21) 700)))
    (setq P23 (list (+ (car p22) 200)                (+ (cadr p2) 850)))
    (setq P24 (list (+ (car p23) 550)                (+ (cadr p2) 100)))
    )
    ((= ART 2)
    (setq P16 (list (- (car p11) 100)                (cadr p0)))
    (setq P17 (list (- (car p2) (- (/ L2 2) 187.5))  (- (cadr p2) (- (/ L2 2) 187.5))))
    (setq P18 (list (+ (car p2) (/ L1 2))            (cadr p2)))
    (setq P19 (list (car p2)                         (- (cadr p18) L2))) 
    (setq P20 (list (- (car p3) 250)                 (+ (cadr p3) 250)))
    (setq P21 (list (+ (car p2) (- (/ L1 2) 300))    (+ (cadr p2) 2000)))
    (setq P22 (list (- (car p21) 700)                (- (cadr p21) 700)))
    (setq P23 (list (+ (car p7) 200)                 (+ (cadr p2) 100)))
    (setq P24 (list (+ (car p7) 350)                 (+ (cadr p2) 850)))
    )
    ((= ART 3)
    (setq P16 (list (+ (car p0) 100)                 (cadr p0)))
    (setq P17 (list (+ (car p2) (- (/ L2 2) 187.5))  (- (cadr p2) (- (/ L2 2) 187.5))))
    (setq P18 (list (+ (car p2) (/ L1 2))            (cadr p2)))
    (setq P19 (list (car p2)                         (- (cadr p18) L2 ))) 
    (setq P20 (list (+ (car p1) 250)                 (+ (cadr p1)  250)))
    (setq P21 (list (car p7)                         (+ (cadr p7)  400)))
    (setq P22 (list (+ (car p21) 1000)               (+ (cadr p21) 700)))
    (setq P23 (list (+ (car p22) 200)                (+ (cadr p2)  850)))
    (setq P24 (list (+ (car p23) 550)                (+ (cadr p2)  100)))
    )
  )
)

(defun geometrie()
  ;-----------------------------------------------------------------------;
  ; >>>>>> Blöcke einfügen  <<<<<<                                        ;
  ;-----------------------------------------------------------------------;
  (command "_layer" "_m" "L-2" "_c" "2" "" "")
  (command "_insert" (strcat lw "/acadsst/layout/w45650l4") P1 "" "" "")
  (setq auswahl-satz (ssget "_L"))
  (command "_insert" (strcat lw "/acadsst/layout/kw800_8x") P2 "" "" "")
  (ssadd (entlast) auswahl-satz)
  (command "_insert" (strcat lw "/acadsst/layout/w45650r4") P3 "" "" "180")
  (ssadd (entlast) auswahl-satz)
  (command "_line" p5 p6 "")
  (ssadd (entlast) auswahl-satz)
  (command "_line" p7 p13 "")
  (ssadd (entlast) auswahl-satz)
  (command "_line" p8 p9 "")
  (ssadd (entlast) auswahl-satz)
  (command "_line" p4 p10 "")
  (ssadd (entlast) auswahl-satz)
  (command "_line" p11 p12 "")
  (ssadd (entlast) auswahl-satz)

  ;-----------------------------------------------------------------------;
  ; >>>>>> Pfeile + Maschinen setzen <<<<<<                               ;
  ;-----------------------------------------------------------------------;
  (command "_layer" "_m" "Z-1" "_c" "1" "" "")
  (cond
    ((= ART 1)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_v") p16 "" "" "")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_l") p17 "" "" "-45")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_v") p18 "" "" "")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_l") p19 "" "" "")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/maus") p22 "" "" "-90")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/vario14") p21 "" "" "180")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/buegelr") p20 "" "" "-45")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pfeil") p23 "" "" "-90")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pfeil") p24 "" "" "120")
      (ssadd (entlast) auswahl-satz)
    )
    ((= ART 2)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_v") p16 "" "" "180")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_l") p17 "" "" "-135")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_v") p18 "" "" "180")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_l") p19 "" "" "180")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/maus") p22 "" "" "-90")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/vario14") p21 "" "" "180")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/buegel") p20 "" "" "45")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pfeil") p23 "" "" "90")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pfeil") p24 "" "" "-60")
      (ssadd (entlast) auswahl-satz)
    )
    ((= ART 3)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_v") p16 "" "" "")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_l") p17 "" "" "-45")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_v") p18 "" "" "")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pf0_l") p19 "" "" "")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/maus") p22 "" "" "90")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/dobli-fw") p21 "" "" "90")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/buegelr") p20 "" "" "-45")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pfeil") p23 "" "" "-90")
      (ssadd (entlast) auswahl-satz)
      (command "_insert" (strcat lw "/acadsst/zier2d/pfeil") p24 "" "" "120")
      (ssadd (entlast) auswahl-satz)
    )
  )
  (If (> K0 1)
      (command "_array" auswahl-satz "" "_r" "1" m_K0 (itoa L1))
  )
) 

;-------------------------------------------------------------------------;
; >>>>>> Programm <<<<<<                                                  ;
;-------------------------------------------------------------------------;
(defun c:b_typ5 (/ L1 L2 L3 KO ART P1 P2 P3 P4 P5 P6 P7 P8 P9 P10 P11 P12 P13 P14 P15 P16 P17 P18 P19 P20 P21 P22 P23 P24)
  (setvar "limcheck" 0)
  (prompt "**** Bügelplatz TYP 5 ****")
  (if (null m_L1)    (setq m_L1       "2800"   ))     ; Breite
  (if (null m_L2)    (setq m_L2       "800"    ))     ; Streckenabstand
  (if (null m_K0)    (setq m_K0       "1"      ))     ; Anzahl der Plätze
  (if (null m_ART)   (setq m_ART      "ART_1"  ))     ; Art
  (setq auswahl-satz nil)
  (Dbox)
  (prompt "")
  (datain)
  (punkte)
  (geometrie)
)
;-------------------------------------------------------------------------;
; >>>>>> Ende <<<<<<                                                      ;
;-------------------------------------------------------------------------;