// ============================================================
// geruest_traeger.dcl - Rohr-Geruest-Traeger konfigurieren (VORLAGE)
// Verwendet von: GERUEST_TRAEGER (GeruestInsert.lsp, geruest-traeger-dialog)
//
// Diese Datei wird NICHT direkt geladen: //@VARIANTEN@ ist ein Platzhalter,
// den GeruestInsert.lsp zur Laufzeit durch einen radio_button je
// Variante (key v<i>, i = Index in geometrie_varianten) ersetzt
// (ssg-dcl-vorlage-fuellen, ssg_core.lsp) - Radiobutton-Labels lassen sich
// per set_tile nicht aendern. Das Ergebnis wird als Temp-Datei geladen.
//
// Jede Variante (auch die mit Muffe) hat einen eigenen Radiobutton, damit
// ihre Artikelnummer sichtbar ist.
//
// Die Laenge steht bewusst NICHT im Dialog - sie wird nach dem Dialog in der
// Zeichnung per Start-/Endpunkt (oder getippter Laenge) bestimmt. Aktive
// Laengenabzuege ruecken die Linie am Anfang bzw. Ende ein.
// ============================================================

geruest_traeger : dialog {
  label = "Rohr-Gerüst-Träger konfigurieren";

  : boxed_column {
    label = "Basis";
    : radio_column {
      key = "variante";
      label = "Variante:";
      alignment = left;
      //@VARIANTEN@
    }
    : row {
      : popup_list { key = "farbe"; label = "Farbe:"; width = 25; }
      : edit_box { key = "farbe_frei"; label = "eigene:"; edit_width = 12; }
    }
  }

  : boxed_column {
    label = "Längenabzug";
    : row {
      : toggle { key = "abzug_a"; label = "Längenabzug Anfang"; width = 24; fixed_width = true; }
      : edit_box { key = "abzug_a_w"; label = "mm:"; edit_width = 8; fixed_width = true; }
    }
    : row {
      : toggle { key = "abzug_e"; label = "Längenabzug Ende"; width = 24; fixed_width = true; }
      : edit_box { key = "abzug_e_w"; label = "mm:"; edit_width = 8; fixed_width = true; }
    }
  }

  : toggle { key = "beschriftung"; label = "Beschriftung einfügen"; }

  : text { key = "hinweis"; label = ""; width = 56; }

  ok_cancel;
}