// ============================================================
// lager.dcl - Dialoge der Lagerplanung (LagerInsert.lsp)
//
// Die Tile-Keys entsprechen den Feldlisten *lg-felder-geschoss*,
// *lg-felder-bereich*, *lg-felder-reihe*, *lg-felder-gang* und
// *lg-felder-kopie* in LagerInsert.lsp
// (generischer Treiber lg-dialog: popup_list fuer Auswahlfelder,
// edit_box fuer alles andere, Pruefung beim OK in lg-dialog-ok).
// Alle Masse in mm.
// ============================================================

lg_geschoss : dialog {
  label = "Lager - Geschoss";
  : column {
    : row {
      : edit_box { key = "nr";          label = "Nummer:";      edit_width = 6; }
      : edit_box { key = "bezeichnung"; label = "Bezeichnung:"; edit_width = 24; }
    }
    : boxed_column {
      label = "Hoehen (mm)";
      : edit_box { key = "hoehe";  label = "Belag Oberkante:";                 edit_width = 10; }
      : edit_box { key = "konstr"; label = "Konstruktionshoehe Belag:";        edit_width = 10; }
      : edit_box { key = "lichte"; label = "Lichte Hoehe (leer = berechnet):"; edit_width = 10; }
    }
    : boxed_column {
      label = "Belag und Fluchtweg-Annahmen";
      : popup_list { key = "belag";    label = "Belagsart:";        width = 34; }
      : edit_box   { key = "personen"; label = "Personen im Geschoss:"; edit_width = 6; }
      : popup_list { key = "brand";    label = "Brandgefaehrdung:"; width = 34; }
    }
  }
  ok_cancel;
  errtile;
}

lg_bereich : dialog {
  label = "Lager - Lagerbereich (Auto-Fuellung)";
  : column {
    : boxed_column {
      label = "Reihen und Gaenge (mm)";
      : edit_box   { key = "gang";     label = "Gangbreite:";      edit_width = 10; }
      : edit_box   { key = "tiefe";    label = "Regaltiefe:";      edit_width = 10; }
      : popup_list { key = "reihen";   label = "Reihen je Gang:";  width = 20; }
      : edit_box   { key = "schienen"; label = "Schienen je Gang:"; edit_width = 10; }
      : edit_box   { key = "richtung"; label = "Reihenrichtung (Grad):"; edit_width = 10; }
    }
    : boxed_column {
      label = "Quergaenge (mm)";
      : edit_box { key = "q_abstand"; label = "Abstand (0 = keine):"; edit_width = 10; }
      : edit_box { key = "q_breite";  label = "Breite:";              edit_width = 10; }
    }
    : boxed_column {
      label = "Randgaenge entlang der Kontur (mm, 0 = keiner; Nord = +Y)";
      : row {
        : edit_box { key = "rand_n"; label = "Nord:"; edit_width = 7; }
        : edit_box { key = "rand_o"; label = "Ost:";  edit_width = 7; }
        : edit_box { key = "rand_s"; label = "Sued:"; edit_width = 7; }
        : edit_box { key = "rand_w"; label = "West:"; edit_width = 7; }
      }
    }
    : boxed_column {
      label = "Haengeware und Belag";
      : edit_box   { key = "ebenen"; label = "Haengeebenen (Schiene/Ware;...):"; edit_width = 24; }
      : popup_list { key = "belag";  label = "Belag der Gaenge:"; width = 30; }
    }
  }
  ok_cancel;
  errtile;
}

lg_gang : dialog {
  label = "Lager - Gang";
  : column {
    : edit_box   { key = "laenge"; label = "Laenge (mm):";  edit_width = 10; }
    : edit_box   { key = "breite"; label = "Breite (mm):";  edit_width = 10; }
    : popup_list { key = "art";    label = "Art:";          width = 30; }
    : popup_list { key = "belag";  label = "Belag:";        width = 30; }
    : text       { label = "Linie: Gang liegt mittig auf der Linie, Breite wie oben."; }
    : text       { label = "Option Rechteck: Flaeche mit RECHTECK zeichnen, Lage und Breite daraus."; }
  }
  ok_cancel;
  errtile;
}

lg_geschoss_kopie : dialog {
  label = "Lager - Geschoss kopieren";
  : column {
    : popup_list { key = "quelle";  label = "Quellgeschoss (Nr.):";        width = 30; }
    : edit_box   { key = "anzahl";  label = "Anzahl neuer Geschosse:";     edit_width = 6; }
    : edit_box   { key = "abstand"; label = "Geschosshoehe je Kopie (mm):"; edit_width = 10; }
    : popup_list { key = "belag";   label = "Belag der neuen Geschosse:";  width = 30; }
    : boxed_column {
      label = "Versatz je Kopie (mm, 0 = deckungsgleich)";
      : row {
        : edit_box { key = "versatz_x"; label = "X:"; edit_width = 10; }
        : edit_box { key = "versatz_y"; label = "Y:"; edit_width = 10; }
      }
    }
    : text { label = "Kopiert Belag, Bereiche, Reihen, Gaenge und goh_rack 1:1."; }
    : text { label = "Belaege gleich dem Quell-Geschossbelag folgen dem neuen Belag."; }
  }
  ok_cancel;
  errtile;
}

lg_reihe : dialog {
  label = "Lager - Regalreihe";
  : column {
    : edit_box { key = "laenge";   label = "Laenge (mm):";     edit_width = 10; }
    : edit_box { key = "tiefe";    label = "Regaltiefe (mm):"; edit_width = 10; }
    : edit_box { key = "ebenen";   label = "Haengeebenen (Schiene/Ware;...):"; edit_width = 24; }
    : edit_box { key = "schienen"; label = "Schienen:";        edit_width = 10; }
  }
  ok_cancel;
  errtile;
}