// ============================================================
// tro_edit.dcl - TRO-Marker bearbeiten bzw. neu anlegen
// Ein Dialog fuer alle TRO-Typen: die Slot-Liste (Separatoren, Weichen,
// Scanner, Antrieb, Lagerlinien) baut Tro_Edit.lsp aus dem Typ auf
// (*TRO-SLOTS* aus tro_types.lsp, erzeugt von sps_skel
// lib/tro_annotate.py --emit-lisp). Die Zeile darunter bearbeitet den
// gewaehlten Slot; "Im Plan waehlen" schliesst den Dialog kurz
// (done_dialog 2) und oeffnet ihn nach der Auswahl wieder.
// Aufruf ueber c:TRO_EDIT und c:TRO_INSERT (Lisp/Tro_Edit.lsp).
// ============================================================

tro_edit : dialog {
  label = "TRO bearbeiten";

  : column {

    : text {
      key = "blockname";
      label = "";
    }

    : row {
      : edit_box {
        key = "id";
        label = "TRO-Kennung:";
        edit_width = 18;
      }
      : popup_list {
        key = "type";
        label = "TRO-Typ:";
        width = 30;
      }
    }

    : boxed_column {
      label = "Bauteile je Slot";

      : list_box {
        key = "slots";
        height = 10;
        width = 50;
        tabs = "14";
        fixed_width_font = true;
      }

      : row {
        : edit_box {
          key = "teil";
          label = "TeileId:";
          edit_width = 10;
        }
        : button {
          key = "pick";
          label = "Im Plan waehlen <";
        }
        : button {
          key = "leeren";
          label = "Leeren";
        }
      }

      : row {
        : button {
          key = "plus";
          label = "+ Lagerlinie";
        }
        : button {
          key = "minus";
          label = "- Lagerlinie";
        }
        : text {
          key = "linien";
          label = "";
          width = 22;
        }
      }
    }

    : text {
      key = "warnung";
      label = "";
      width = 62;
    }

    : text {
      key = "fb";
      label = "";
    }

    : text {
      key = "hinweis";
      label = "";
    }

  }

  ok_cancel;
}