=== FC 2181: VPtoEP_Ziel_FC  [STL] ===
INTERFACE:
  Input:
  Output:
  InOut:
  Temp:
    Ziel_hex : Word
    Ziel_int : Int
    Zielebene : Word
    Error : Byte
    Position : Int
    Lager_DB : Int
    Lager_DW : Int
    AR1Zeiger : DWord                                   // Statt AR1 (ging nur bis DB-Länge <= 8191 Bytes)
    AR1Start : DInt                                     // Startwert mit Offset 0
    SSDW : Int
    EndZiel : Word
    Variante : Int
    AbrufID : DInt
    Fahrlisten_TrolleyID : DInt
    Fahrlisten_AbrufID : DInt
    Fahrlisten_Lager : Int
    Trolley_unbekannt : Bool                            // Trolley ist nicht in DL
    Express_Abruf : Bool
  Constant:
  Return:
    Ret_Val : Void

--- NW 1: Rückmeldung ---
      SET                                                    // Rückmeldungen erst mal resetten
      R      "M180.6"                                        // Weiterfahrt von Ziel-FC erlaubt


--- NW 2: Bereich 3361: Weiterfahren erlaubt ? (Ende MA0060) ---
      L      "MW190"
      L      3361                                            // Aufruf von Schleuse 3361 ?
      <>I                                                    // Nein!
      JC     X3361E

      AN     "DVPtoEP_Sensoren".Stau_BG3362.Stat.B_Akt
      S      "M180.6"                                        // Weiterfahrt ist erlaubt

      BEU

X3361E: NOP 0


--- NW 3: Schleuse 3366: (BST 1) ---
      L      "MW190"
      L      3366                                            // Aufruf von Schleuse XXXX?
      <>I                                                    // Nein!
      JC     X3366E

      SET
      S      "M180.6"                                        // Weiterfahrt ist erlaubt

      BEU

X3366E: NOP 0


--- NW 4: Bereich 4441: Weiterfahren erlaubt ? (Ende MA0320) ---
      L      "MW190"
      L      4441                                            // Aufruf von Schleuse 4441 ?
      <>I                                                    // Nein!
      JC     X4441E

      AN     "DVPtoEP_Sensoren".Stau_BG4442.Stat.B_Akt
      S      "M180.6"                                        // Weiterfahrt ist erlaubt

      BEU

X4441E: NOP 0


--- NW 5: Schleuse 4443: (Vor ByPass zurück zu LP) ---
      L      "MW190"
      L      4443                                            // Aufruf von Schleuse XXXX?
      <>I                                                    // Nein!
      JC     PS5E

// Ziel-Check:
      L      "DVPtoEP_OmniFahren".Schleuse_4443.Dyn.Trolley_ShopGroup
      L      DINT#-1                                         // leerer Trolley ?
      ==D                                                    // Ja !
      AN     "DVPtoEP_Sensoren".Sack_BG4444.Stat.B_Akt       // Kein Sack erkannt
      JC     A4443                                           // Abzweig fahren

      JU     G4443                                           // Rest Gerade fahren

A4443: L      16#4461
      T      "MW198"                                         // Weichenziel

// Quell-Steuerung:
      L      "DEPtoLP_OmniFahren".Schleuse_4466.Dyn.Raus_Trolleys
      L      0                                               // Sind Trolleys zur Weiche MB4210 unterwegs?
      >I                                                     // Ja!
      O      "DEPtoLP_OmniFahren".Schleuse_4466.Dyn.Status.Reset_aktiv
      O      "MB4466"                                        // Andere Quelle aktiv
      BEC

      AN     "DEPtoLP_Sensoren".Stau_BG4461.Stat.B_Akt
      S      "M180.6"                                        // Weiterfahrt ist erlaubt

      BEU

G4443: L      16#4447
      T      "MW198"                                         // Weichenziel

      AN     "DVPtoEP_Sensoren".Stau_BG4447.Stat.B_Akt
      S      "M180.6"                                        // Weiterfahrt ist erlaubt

      BEU

PS5E: NOP 0


--- NW 6: Ende ---
      BE

