=== FC 125: Err_vorhanden  [STL] ===
INTERFACE:
  Input:
    Check_DB : Int
    Anfangs_DW : DInt
    Ende_DW : DInt
  Output:
    Stoerung : Bool                                     // Störung vorhanden
    ErrDW : DInt
    ErrBits : Int
  InOut:
  Temp:
    Anzeige_DB : Int
    Zeiger : DInt                                       // Startwert mit Offset 0
    AR1Zeiger : DWord                                   // Statt AR1 (ging nur bis DB-Länge <= 8191 Bytes)
  Constant:
  Return:
    Ret_Val : Void

--- NW 1: Check-DB von "Abfangs_DW" bis "Ende_DW" checken ---
      SET                                                    // GST
      R      Stoerung
      L      DINT#-1                                         // Sonst Störung in DBD0 nicht erkennbar
      T      ErrDW
      L      0
      T      ErrBits

      L      Check_DB
      T      Anzeige_DB

      L      Anfangs_DW                                      // Mit diesem DW beginnen
      T      Zeiger                                          // Zeiger

Loop: L      Zeiger                                          // Zeiger
      SLD    3
      T      AR1Zeiger                                       // Statt Dyn.Bereichsstop (ging nur bis DB-Länge <= 8191 Bytes)

      OPN    DB[Anzeige_DB]

      L      DBW [AR1Zeiger]                                 // Störungsbits
      T      ErrBits
      L      0                                               // aktiv ?
      <>I                                                    // Ja !
      JC     Err

      L      Zeiger                                          // Startwert mit Offset 0
      L      2
      +D
      T      Zeiger                                          // Zeiger
      L      Ende_DW                                         // Letztes DW überschritten?
      <=D                                                    // Nein !
      JC     Loop

      BEU

Err:  SET
      S      Stoerung

      L      Zeiger                                          // Zeiger
      T      ErrDW


--- NW 2: Ende ---
      BE

