=== FC 6181: LPtoHW_Ziel_FC  [STL] ===
INTERFACE:
  Input:
  Output:
  InOut:
  Temp:
    Ziel_hex : Word
    Ziel_int : Int
    Zielebene : Word
    Error : Byte
    Position : Int
    Lager_DB : Int
    Lager_DW : Int
    AR1Zeiger : DWord                                   // Statt AR1 (ging nur bis DB-Länge <= 8191 Bytes)
    AR1Start : DInt                                     // Startwert mit Offset 0
    SSDW : Int
    EndZiel : Word
    Variante : Int
    AbrufID : DInt
    Fahrlisten_TrolleyID : DInt
    Fahrlisten_AbrufID : DInt
    Fahrlisten_Lager : Int
    Trolley_unbekannt : Bool                            // Trolley ist nicht in DL
    Express_Abruf : Bool
  Constant:
  Return:
    Ret_Val : Void

--- NW 1: Rückmeldung ---
      SET                                                    // Rückmeldungen erst mal resetten
      R      "M180.6"                                        // Weiterfahrt von Ziel-FC erlaubt


--- NW 2: Schleuse 3342: Weiterfahren erlaubt ? (Vor Trolley-Beladung) ---
      L      "MW190"
      L      3342                                            // Aufruf von Schleuse 3342 ?
      <>I                                                    // Nein!
      JC     X3342E

      SET
      S      "M180.6"                                        // Weiterfahrt ist erlaubt

      BEU

X3342E: NOP 0


--- NW 3: Schleuse 3323: Weiterfahren erlaubt ? (Trolley-Beladung) ---
      L      "MW190"
      L      3323                                            // Aufruf von Schleuse 3323 ?
      <>I                                                    // Nein!
      JC     X3323E

// Umschalten auf Durchfahr-Modus:
      A      "DLeerPufferStrecken".DurchfahrModus.Anmelden
      AN     "DLPtoHW_Sensoren".Sack_BG3324.Stat.B_Akt       // Noch kein Sack behängt
      R      "DLeerPufferStrecken".DurchfahrModus.Anmelden
      S      "DLeerPufferStrecken".DurchfahrModus.Aktiv

// Trolley-Err-Anzeige (blau):
      A      "BG3323"                                        // Trolley ist in Schleuse
      A(
      A      "DLeerPufferStrecken".DurchfahrModus.Aktiv
      A      "DLPtoHW_Sensoren".Sack_BG3324.Stat.B_Akt       // Aber Sack behängt
      O
      AN     "DLeerPufferStrecken".DurchfahrModus.Aktiv
      AN     "DLPtoHW_Sensoren".Sack_BG3324.Stat.B_Akt       // Noch kein Sack behängt
      )
      =      "PF0033"

// Trolley kann gestartet werden:
      A      "BG3323"                                        // Trolley ist in Schleuse
      AN     "DLeerPufferStrecken".DurchfahrModus.Aktiv
      A      "DLPtoHW_Sensoren".Sack_BG3324.Stat.B_Akt       // Sack behängt
      A      "Clock_2Hz"
      =      "PF0044"

// Bestätigung durch Bediener:
      A      "BG3323"                                        // Trolley ist in Schleuse
      A(
      A      "SF0044"                                        // Bestätigung mit Taster
      AN     "DLeerPufferStrecken".DurchfahrModus.Aktiv
      A      "DLPtoHW_Sensoren".Sack_BG3324.Stat.B_Akt       // Sack behängt
      O
// Durchfahr-Modus aktiv:
      A      "DLeerPufferStrecken".DurchfahrModus.Aktiv
      AN     "DLPtoHW_Sensoren".Sack_BG3324.Stat.B_Akt       // Aber Sack behängt
      )
      S      "M180.6"                                        // Weiterfahrt ist erlaubt

      BEU

X3323E: NOP 0


--- NW 4: Schleuse 4221: (Vor ByPass zum VP) ---
      L      "MW190"
      L      4221                                            // Aufruf von Schleuse XXXX?
      <>I                                                    // Nein!
      JC     PS5E

// Ziel-Check:
      L      "DLPtoHW_OmniFahren".Schleuse_4221.Dyn.Trolley_EndZiel
      L      16#B000                                         // Vollpuffer ?
      ==I                                                    // Ja !
      AN     "DLPtoHW_Sensoren".Sack_BG4222.Stat.B_Akt       // Kein Sack erkannt
      JC     A4221                                           // Abzweig fahren

      JC     G4221

      JU     G4221                                           // Rest Gerade fahren

// Abzweig fahren:
A4221: L      16#4211
      T      "MW198"                                         // Weichenziel

// Quell-Steuerung:
      L      "DHWtoVP_OmniFahren".Schleuse_4207.Dyn.Raus_Trolleys
      L      0                                               // Sind Trolleys zur Weiche MB4210 unterwegs?
      >I                                                     // Ja!
      O      "DHWtoVP_OmniFahren".Schleuse_4207.Dyn.Status.Reset_aktiv
      O      "MB4207"                                        // Andere Quelle aktiv
      BEC

      AN     "DHWtoVP_Sensoren".Stau_BG4210.Stat.B_Akt
      AN     "DHWtoVP_Sensoren".Stau_BG4211.Stat.B_Akt
      S      "M180.6"                                        // Weiterfahrt ist erlaubt

      BEU

// Gerade fahren:
G4221: L      16#4224
      T      "MW198"                                         // Weichenziel

      AN     "DLPtoHW_Sensoren".Stau_BG4224.Stat.B_Akt
      S      "M180.6"                                        // Weiterfahrt ist erlaubt

      BEU

PS5E: NOP 0


--- NW 5: Schleuse 4235: (BST 2) ---
      L      "MW190"
      L      4235                                            // Aufruf von Schleuse XXXX?
      <>I                                                    // Nein!
      JC     X4235E

      SET
      S      "M180.6"                                        // Weiterfahrt ist erlaubt

      BEU

X4235E: NOP 0


--- NW 6: Schleuse 3722: Übergabe an UH06/AMR ---
      L      "MW190"
      L      3722                                            // Aufruf von Schleuse 3722 ?
      <>I                                                    // Nein!
      JC     X3722E

      SET
      S      "M180.6"                                        // Weiterfahrt ist erlaubt

      BEU

X3722E: NOP 0


--- NW 7: Ende ---
      BE

